2018年08月30日

夏休みの宿題ゲーム for Ichigojam

この記事は、クエリちゃん x プロ生ちゃん 夏休み #プチプログラミング コンテスト2018応募用の記事っぽいです。

夏休みの宿題ゲーム
このゲームは8月31日までに100ページもある夏休みの友(宿題帳)をやり終えるゲームです。
ゲームを実行すると7月20日の晩から始まります。
あなたは次の日の予定を決めてから寝ることにしています。
また、予定を決めたらその通りに実行する几帳面なひとなのです。
明日の天気予報(晴れ、曇り、雨)がパーセントで表示されますので
それを参考に明日のやることを決めます。
※予報なのでもちろん想定外な天気なこともありそうです。

・宿題をする(1を選択)
100ページもある夏休みの宿題帳をやります。天気が悪いほうが
どちらかというとはかどります。
・遊ぶ(2を選択)
せっかくの夏休みなんだから遊びます。遊ぶとやる気が充実します。
天気がよいと充実しやすいですが雨の日はちょっぴり残念です。
・寝る(3を選択)
天気に関係なく寝てしまいます。ゆっくり休んだらやる気が充実する
こともあるかもしれません。
数字を入力したらエンターキーで決定です。

明日のやることを入力したらもう次の日です。
今日の天気が表示されて決めたことをやります。
宿題をやると進んだページ数が表示されます。
やる気があると多めにページ数をこなせそうです。
遊んだり寝るとやる気が充実しますが、充実度は
小←「v」「>」「^」→大
で表現されています。
そうこうしているうちにもう夜なので次の日の予定を決めます。

こうして42日間の夏休み中に100ページの宿題帳をやりとげればクリアです!
ただし、夏休みが終わってしまうとゲームオーバーです。

うーん、これってゲームか?夏休み中ずっと宿題やってればいいじゃん!と
思うかもしれませんが、天候にもよりますが夏休み中ずっと宿題やってても
やる気が続かずに終わらないようになってますので、天気のいい日は遊びましょう。
とはいうものの現実では健康にかかわるほどの酷暑ですのでそうも言ってられないかも。
ていうかもう夏休み終わりですよね。
今思うと超大昔に天気が関係するゲームってなんかあったような気がしますよね…

ソースというかプログラムリストはこちら。
100 LET[1],"HARE","KUMORI","AME",100,"v",">","^"
110 Y=20:N=0:P=0
120 PRINT"7/20 ASHITA KARA NATSUYASUMI!":?
130 @LOOP:N=N+1:IF Y>100 THEN Y=100
140 H=RND(98)+1:K=RND(98-H)+1:A=100-H-K:T=RND(100)+1
150 E=(H<=T)+((K+H)<=T)+1:R=(Y>30)+(Y>70)+5
160 PRINT"SHUKUDAI:";P;"PAGE YARUKI:";STR$([R])
170 IF N>42 THEN PRINT"NATSUYASUMIHA OWARIMASITA..ZANNEN..":END
180 IF N<12 THEN PRINT"7/";N+20; ELSE PRINT"8/";N-11;
190 PRINT" TENKIYOHOU HARE:";H;"% KUMORI:";K;"% AME:";A;"%"
200 @D:INPUT"DOUSURU?(1:SHUKUDAI 2:ASOBU 3:NERU):",D
210 IF D<1 OR D>3 GOTO @D
220 PRINT"KYOU NO TENKI:";STR$([E])
230 IF D=1 GOTO @SKD ELSE IF D=2 GOTO @ASB
240 PRINT"NETARA...SUKKIRI!?":Y=Y+RND(30):GOTO @RTN
250 @SKD:W=RND(2)+E:IF Y>=20 THEN Y=Y-20:W=W+RND(2)+2
260 IF (P+W)>100 THEN W=100-P
270 PRINT"SHUKUDAI:";W;"PAGE YATTA!":P=P+W:GOTO @RTN
280 @ASB:W=(RND(10)+30)*(E=1):W=W+(RND(20)+10)*(E=2)
290 W=W+RND(10)*(E=3):Y=Y+W
300 PRINT"YARUKIGA AGATTA!"
310 @RTN:PRINT"----":IF P<[4] GOTO @LOOP
320 PRINT"SHUKUDAI:";[4];"PAGE OWATTA! OMEDETOU!":END
プログラムは自由に変えて遊んでみてください、といってももうほとんどメモリは残っていませんが…。
メモリの節約のため、150行や280行などが普通ではない記述になっています。
たとえば、(E=2) なんてありますが、これはEに2を入れているのではなくてEと2を比較しています。
比較した結果が正しければ、(E=2)は1の値になり、正しくなれば0の値になります。
これを応用して R=(Y>30)+(Y>70)+5 の例ですと、Yが60だとしたら R=(1)+(0)+5 となってR=6になります。
上手く使えばIF文を何個も書かなくて済むのでメモリと処理時間の節約にもなりますよ!

表示メッセージがアルファベットのローマ字になっていて読みづらくてすみません。
Ichigojamはカタカナも扱えるのですが、コード体系が違うため実機以外のIchigojam Webや
プログラムリストをウェブに掲載する際に文字が化けてしまうのでやむなくローマ字としました。
実機で遊ぶ際はカタカナで手入力すれば文字数が減るのでメモリが節約できるかも。

こちらからIchigojam Webで実機が無くてもブラウザからでも楽しめます。
RUNとキーボードから入力してエンターキーを押すとゲームが実行されます。
スマホでは(物理的な)キーボードが無いのでゲームの実行や操作ができないのではないかと思われます…。
posted by まちゅ at 23:15| Comment(0) | プログラミング
この記事へのコメント
コメントを書く
お名前:

メールアドレス:

ホームページアドレス:

コメント: